Quote from luishp on February 28, 2019, 11:36 pm

I think dec_pack_es.zip has quite a lot of those functionalities:
https://sites.google.com/site/pluginsneobook/home/descargar

Regards.

Quote from impactband4u on March 1, 2019, 9:10 am

GetSystemInfo - Function

Here is a Function that get System Information. Don't know if it have harddrive and cpu

{NeoBook Function}
Version=5.80
Language=VBScript
Comment=getSystemInfo|Version 1.1|Function for NeoBook for Windows|By Michael Weiner <mailto:neobook@cogit.net>|15 August 2015|This function returns information about the computer system.
Param=[%model]|Variable|Manufacturer and model
Param=[%os]|Variable|Operating system and version
Param=[%sp]|Variable|Service pack
Param=[%mem]|Variable|Total physical memory (MB)
Param=[%freeMem]|Variable|Free physical memory (MB)
Param=[%cpu]|Variable|Processor
Param=[%cpuType]|Variable|Processor type
Param=[%bios]|Variable|BIOS
Param=[%motherboard]|Variable|Motherboard
{End}
On Error Resume Next
strComputer = "."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colSettings
 os = trim(objOperatingSystem.Caption)
 ver = objOperatingSystem.Version
 sp = objOperatingSystem.ServicePackMajorVersion & "." & objOperatingSystem.ServicePackMinorVersion
 freeMem = int(objOperatingSystem.FreePhysicalMemory/1024)
Next
Set colSettings = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings
 mfg = objComputer.Manufacturer
 model = objComputer.Model
 mem = int(objComputer.TotalPhysicalMemory/1048576)
Next
model = append(mfg,model,model)
Set colSettings = objWMIService.ExecQuery("Select * from Win32_Processor")
For Each objProcessor in colSettings
 cpu = objProcessor.Name
 cpuType = objProcessor.Description
 winBitness = objProcessor.AddressWidth
 cpuBitness = objProcessor.DataWidth
Next
os = append(os,winBitness,winBitness & "-bit")
os = append(os,ver,"Version " & ver)
cpu = append(cpu,cpuBitness,cpuBitness & "-bit")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_BIOS")
For Each objBIOS in colSettings
 bios = objBIOS.Manufacturer
 bName = objBIOS.Name
 bVer = objBIOS.SMBIOSBIOSVersion
Next
bios = append(bios,bName,bName)
bios = append(bios,bVer,bVer)
Set colSettings = objWMIService.ExecQuery("Select * from Win32_BaseBoard")
For Each objBaseboard in colSettings
 motherboard = objBaseboard.Manufacturer
 mProduct = objBaseboard.Product
 mVer = objBaseboard.Version
Next
motherboard = append(motherboard,mProduct,mProduct)
motherboard = append(motherboard,mVer,mVer)
Function append(s1,s2,s3)
 append = s1
 If s2 > "" Then
  append = append & " " & s3
 End If
End Function
publication.nbSetVar "[%model]", model
publication.nbSetVar "[%os]", os
publication.nbSetVar "[%sp]", sp
publication.nbSetVar "[%mem]", mem
publication.nbSetVar "[%freeMem]", freeMem
publication.nbSetVar "[%cpu]", cpu
publication.nbSetVar "[%cpuType]", cpuType
publication.nbSetVar "[%bios]", bios
publication.nbSetVar "[%motherboard]", motherboard

 

Quote from impactband4u on March 1, 2019, 9:13 am

It's got cpu info : ) sorry

Quote from s7shanbe on March 1, 2019, 5:43 pm

Is there a function that shows the serial number of the hard disk?

Quote from s7shanbe on March 1, 2019, 5:44 pm

Quote from luishp on February 28, 2019, 11:36 pm

I think dec_pack_es.zip has quite a lot of those functionalities:
https://sites.google.com/site/pluginsneobook/home/descargar

Regards.

This link is not open to me

Quote from luishp on March 2, 2019, 10:04 am

This link is not open to me

Here it is.